Proof-of-concept: _implements trait

Author: fingolfin

src/FreeAssociativeAlgebra.jl

@@ -136,6 +136,8 @@ function is_unit(a::FreeAssociativeAlgebraElem{T}) where T
    end
 end
 
+_implements(::Type{FreeAssociativeAlgebraElem{T}}, f::typeof(is_unit)) where T = is_domain_type(T) || _implements_directly(T, f)
+
 ###############################################################################
 #
 # Hashing

src/MPoly.jl

@@ -437,6 +437,8 @@ function is_unit(f::T) where {T <: MPolyRingElem}
   return constant_term_is_unit  # handles the case that there is no constant term
 end
 
+_implements(::Type{MPolyRingElem{T}}, ::typeof(is_unit)) where T = _implements(T, is_unit) && _implements(T, is_nilpotent)
+
 function content(a::MPolyRingElem{T}) where T <: RingElement
    z = zero(coefficient_ring(a))
    for c in coefficients(a)
@@ -452,12 +454,16 @@ function is_nilpotent(f::T) where {T <: MPolyRingElem}
   return all(is_nilpotent, coefficients(f))
 end
 
+_implements(::Type{MPolyRingElem{T}}, ::typeof(is_nilpotent)) where T = _implements(T, is_nilpotent)
+
 
 function is_zero_divisor(x::MPolyRingElem{T}) where T <: RingElement
   is_domain_type(T) && return is_zero(x)
   return is_zero_divisor(content(x))
 end
 
+_implements(::Type{MPolyRingElem{T}}, ::typeof(is_zero_divisor)) where T = _implements(T, is_zero_divisor)
+
 function is_zero_divisor_with_annihilator(a::MPolyRingElem{T}) where T <: RingElement
    f, b = is_zero_divisor_with_annihilator(content(a))
    return f, parent(a)(b)

src/NCPoly.jl

@@ -785,3 +785,36 @@ polynomial_ring_only(R::T, s::Symbol; cached::Bool=true) where T<:NCRing =
 
 PolyRing(R::NCRing) = polynomial_ring_only(R, :x; cached=false)
 
+
+###############################################################################
+#
+#   is_unit & is_nilpotent
+#
+###############################################################################
+
+# ASSUMES structural interface is analogous to that for univariate polynomials
+
+# This function handles both PolyRingElem & NCPolyRingElem
+function is_unit(f::T) where {T <: PolynomialElem}
+  # constant coeff must itself be a unit
+  is_unit(constant_coefficient(f)) || return false
+  is_constant(f) && return true
+  # Here deg(f) > 0; over an integral domain, non-constant polynomials are never units:
+  is_domain_type(T) && return false
+  for i in 1:degree(f) # we have already checked coeff(f,0)
+    if !is_nilpotent(coeff(f, i))
+      return false
+    end
+  end
+  return true
+end
+
+# This function handles both PolyRingElem & NCPolyRingElem
+function is_nilpotent(f::T) where {T <: PolynomialElem}
+  is_domain_type(T) && return is_zero(f)
+  return all(is_nilpotent, coefficients(f))
+end
+
+_implements(::Type{PolynomialElem{T}}, ::typeof(is_unit)) where T = _implements(T, is_unit) && _implements(T, is_nilpotent)
+
+_implements(::Type{PolynomialElem{T}}, ::typeof(is_nilpotent)) where T = _implements(T, is_nilpotent)

src/NCRings.jl

@@ -175,6 +175,8 @@ function is_nilpotent(a::T) where {T <: NCRingElement}
   throw(NotImplementedError(:is_nilpotent, a))
 end
 
+_implements(::Type{T}, f::typeof(is_nilpotent)) where {T <: NCRingElement} = is_domain_type(T) || _implements_directly(T, f)
+
 
 ###############################################################################
 #

src/algorithms/GenericFunctions.jl

@@ -429,6 +429,8 @@ function is_zero_divisor(a::T) where T <: RingElement
    return is_zero(a) && !is_trivial(parent(a))
 end
 
+_implements(::Type{T}, f::typeof(is_zero_divisor)) where {T} = is_domain_type(T) || _implements_directly(T, f)
+
 @doc raw"""
     is_zero_divisor_with_annihilator(a::T) where T <: RingElement
 
@@ -456,6 +458,8 @@ function factor(a)
    throw(NotImplementedError(:factor, a))
 end
 
+_implements(::Type{T}, f::typeof(factor)) where {T} = _implements_directly(T, f)
+
 @doc raw"""
     factor_squarefree(a::T) where T <: RingElement -> Fac{T}
 
@@ -466,6 +470,8 @@ function factor_squarefree(a)
    throw(NotImplementedError(:factor_squarefree, a))
 end
 
+_implements(::Type{T}, f::typeof(factor_squarefree)) where {T} = _implements_directly(T, f)
+
 @doc raw"""
     is_irreducible(a::RingElement)
 
@@ -479,6 +485,8 @@ function is_irreducible(a)
    return length(af) == 1 && all(isone, values(af.fac))
 end
 
+_implements(::Type{T}, ::typeof(is_irreducible)) where {T} = _implements(T, is_unit) && _implements(T, factor)
+
 @doc raw"""
     is_squarefree(a::RingElement)
 
@@ -493,3 +501,4 @@ function is_squarefree(a)
    return all(isone, values(af.fac))
 end
 
+_implements(::Type{T}, ::typeof(is_squarefree)) where {T} = _implements(T, is_unit) && _implements(T, factor_squarefree)

src/algorithms/LaurentPoly.jl

@@ -159,6 +159,10 @@ function is_nilpotent(f::T) where {T <: LaurentPolyRingElem}
   return is_nilpotent(f.poly);
 end
 
+_implements(::Type{LaurentPolyRingElem{T}}, ::typeof(is_unit)) where T = _implements(T, is_unit) && _implements(T, is_nilpotent)
+
+_implements(::Type{LaurentPolyRingElem{T}}, ::typeof(is_nilpotent)) where T = _implements(T, is_nilpotent)
+
 
 ###############################################################################
 #

src/fundamental_interface.jl

@@ -452,3 +452,59 @@ function _number_of_direct_product_factors end
 Return the homomorphism from the domain `D` into the codomain `C` defined by the data.
 """
 function hom end
+
+###############################################################################
+#
+#
+#
+###############################################################################
+
+# Calling `_implements(T, f)` checks whether a "sensible" method for the unary
+# function `f` is implemented for inputs of type `T`. The argument order is
+# meant to be similar to e.g. `isa`, and thus indicates `T implements f`.
+#
+# For example, `_implements(MyRingElem, is_unit)` should return true if
+# invoking `is_unit` on elements of type `MyRingElem` is supported.
+#
+# The generic fallback uses `hasmethod`. However, this may return `true` in
+# cases where it shouldn't, as we often provide generic methods for that rely
+# on other methods being implemented -- either for the same type, or for types
+# derived from it. For example the `is_nilpotent(::PolyElem{T})` method needs
+# `is_nilpotent(::T)` in order to work.
+#
+# To reflect this, additional `_implements` methods need to be provided.
+# We currently do this for at least the following functions:
+# - factor
+# - is_irreducible
+# - is_nilpotent
+# - is_squarefree
+# - is_unit
+# - is_zero_divisor
+#
+_implements(::Type{T}, f::Any) where {T} = hasmethod(f, Tuple{T})
+
+# Alternatively, the first argument can be a concrete object. By default we
+# then redispatch to the type based version. But one may also choose to
+# implement custom methods for this: certain operations will only work for
+# *some* instances. E.g. for `Z/nZ` it may happen that for `n` a prime we can
+# perform a certain operation, but not if `n` is composite.
+#
+# In that case the recommendation is that `_implements` invoked on the type
+# returns `false`, but invoked on a concrete instance of a type, it may use
+# specifics of the instance to also return `true` if appropriate.
+function _implements(x::T, f::Any) where {T}
+  @assert !(x isa Type) # paranoia
+  return _implements(T, f)
+end
+
+# helper for `_implements` which checks if `f` has a method explicitly for
+# a concrete type `T` (i.e. not a generic method that can be specialized to `T`
+# but really one that is implement for `T` and `T` only).
+function _implements_directly(::Type{T}, f::Any) where {T}
+  isconcretetype(T) || return false  # TODO: drop this?
+  meth = methods(f, Tuple{T})
+  # TODO: deal with type parameters: if `T` is `FreeAssociativeAlgebraElem{ZZRingElem}`
+  # and `f` has a method for `FreeAssociativeAlgebraElem` then we should still consider
+  # this a match.
+  return any(m -> m.sig == Tuple{typeof(f), T}, meth)
+end

src/generic/LaurentMPoly.jl

@@ -131,6 +131,10 @@ function is_nilpotent(f::T) where {T <: LaurentMPolyRingElem}
   return is_nilpotent(f.mpoly);
 end
 
+_implements(::Type{LaurentMPolyRingElem{T}}, ::typeof(is_unit)) where T = _implements(T, is_unit) && _implements(T, is_nilpotent)
+
+_implements(::Type{LaurentMPolyRingElem{T}}, ::typeof(is_nilpotent)) where T = _implements(T, is_nilpotent)
+
 
 is_zero_divisor(p::LaurentMPolyWrap) = is_zero_divisor(p.mpoly)