SQLite write support

Author: King-Ozymandias

README.md

@@ -28,7 +28,7 @@ EpMonitor disableDuring: [
       load ].
 ```
 
-If you'd be interested in (basic, read-only for now) SQLite support, use `load: 'sqlite'` at the end:
+If you'd be interested in SQLite support, use `load: 'sqlite'` at the end:
 
 ```st
 EpMonitor disableDuring: [
@@ -130,11 +130,20 @@ weather transposed.
 | **2** | true | true | false | true | true |
 | **3** | snow | rain | -     | rain | snow |
 
-### Load data from SQLite query:
+### SQLite examples
+*Following examples expect valid/connected SQLite connection in a variable `conn`*
+#### Load data from SQLite query:
 ```st
-"If you have a connection ready in conn"
 df := DataFrame readFromSqliteCursor: (conn execute: 'SELECT * FROM table').
 ```
+#### Write data to SQLite table (DataFrame column names <=> table column names):
+```st
+df writeToSqlite: conn tableName: 'table'.
+```
+#### Write to differently named colums (provide names for ALL DataFrame columns!)
+```st
+df writeToSqlite: conn tableName: 'table' columnNames: #('col1' 'col2' 'col3').
+```
 
 ## Documentation and Literature
 

src/DataFrame-IO-Sqlite/DataFrame.extension.st

@@ -5,3 +5,21 @@ DataFrame class >> readFromSqliteCursor: aSqliteCursor [
 	"Convenience shortcut for SQLite3Cursor => DataFrame"
 	^ self readFrom: aSqliteCursor using: DataFrameSqliteReader new
 ]
+
+{ #category : '*DataFrame-IO-Sqlite' }
+DataFrame >> writeToSqlite: aSqlite3Connection tableName: aString [
+
+	| writer |
+	writer := DataFrameSqliteWriter writeToTable: aString.
+	self writeTo: aSqlite3Connection using: writer
+]
+
+{ #category : '*DataFrame-IO-Sqlite' }
+DataFrame >> writeToSqlite: aSqlite3Connection tableName: aString columnNames: aCollection [
+
+	| writer |
+	writer := DataFrameSqliteWriter
+		          writeToTable: aString
+		          columnNames: aCollection.
+	self writeTo: aSqlite3Connection using: writer
+]

src/DataFrame-IO-Sqlite/DataFrameSqliteWriter.class.st

@@ -0,0 +1,85 @@
+Class {
+	#name : 'DataFrameSqliteWriter',
+	#superclass : 'DataFrameWriter',
+	#instVars : [
+		'tableName',
+		'columnNames'
+	],
+	#category : 'DataFrame-IO-Sqlite',
+	#package : 'DataFrame-IO-Sqlite'
+}
+
+{ #category : 'instance creation' }
+DataFrameSqliteWriter class >> writeToTable: aString [
+
+	^ self new
+		  tableName: aString;
+		  yourself
+]
+
+{ #category : 'instance creation' }
+DataFrameSqliteWriter class >> writeToTable: aString columnNames: aCollection [
+
+	^ self new
+		  tableName: aString;
+		  columnNames: aCollection;
+		  yourself
+]
+
+{ #category : 'accessing' }
+DataFrameSqliteWriter >> columnNames [
+
+	^ columnNames
+]
+
+{ #category : 'accessing' }
+DataFrameSqliteWriter >> columnNames: anObject [
+
+	columnNames := anObject
+]
+
+{ #category : 'helpers' }
+DataFrameSqliteWriter >> getColumnNamesFor: aDataFrame [
+
+	columnNames ifNil: [ ^ aDataFrame columnNames ].
+	columnNames size ~= aDataFrame columns size ifTrue: [
+		self error:
+			'Column count mismatch (Writer columns <=> DataFrame columns)' ].
+	^ columnNames
+]
+
+{ #category : 'helpers' }
+DataFrameSqliteWriter >> insertQueryForColumns: aSequence [
+	""
+	^ String streamContents: [ :strm |
+		strm
+			nextPutAll: 'INSERT INTO ';
+			nextPutAll: tableName;
+			nextPut: $(;
+			nextPutAll: (',' join: aSequence);
+			nextPutAll: ')VALUES('.
+		aSequence do: [ :ignore | strm nextPut: $? ] separatedBy: [ strm nextPut: $, ].
+		strm nextPut: $) ]
+]
+
+{ #category : 'accessing' }
+DataFrameSqliteWriter >> tableName [
+
+	^ tableName
+]
+
+{ #category : 'accessing' }
+DataFrameSqliteWriter >> tableName: anObject [
+
+	tableName := anObject
+]
+
+{ #category : 'writing' }
+DataFrameSqliteWriter >> write: aDataFrame to: aSqliteConnection [
+
+	| stmt |
+	stmt := aSqliteConnection prepare:
+		        (self insertQueryForColumns:
+			         (self getColumnNamesFor: aDataFrame)).
+	aDataFrame do: [ :row | stmt execute: row asArray ]
+]