Make leak detector robust against leaks from preceding tests

[A CI test
run](https://app.circleci.com/pipelines/github/clj-commons/aleph/769/workflows/1be2f5bc-92a9-4768-aa93-845365476aaf/jobs/753/parallel-runs/0/steps/0-107)
recently failed with this error coming from the resource leak detector:

    ERROR in (test-basic-auth-value-encoding) (core.clj:2362)
    expected: (= "Basic Og==" (middleware/basic-auth-value nil))
      actual: java.lang.ClassCastException: clojure.lang.Var$Unbound cannot be cast to clojure.lang.IAtom
     at clojure.core$swap_BANG_.invokeStatic (core.clj:2362)
        clojure.core$swap_BANG_.invoke (core.clj:2362)
        aleph.resource_leak_detector$_reportTracedLeak.invokeStatic (resource_leak_detector.clj:138)
        aleph.resource_leak_detector$_reportTracedLeak.invoke (resource_leak_detector.clj:137)
        aleph.resource_leak_detector.reportTracedLeak (:-1)

However, the test namespace in question isn't even instrumented for leak detection (i.e. there is no
`aleph.resource-leak-detector/instrument-tests!` call at its bottom). Immediately before this error,
there is another one, though:

    ERROR in (test-shutdown-timeout-1) (resource_leak_detector.clj:103)
    Uncaught exception, not in assertion.
    expected: nil
      actual: java.lang.RuntimeException: Gave up awaiting leak probe. Try increasing `aleph.resource-leak-detector/max-probe-gc-runs`.

This indicates that there was still a pending leak detection probe which was then (attempted to be)
reported in the context of the following test. To prevent such red herrings in the future, we now
gracefully report such leaked leaks.

Author: DerGuteMoritz

test/aleph/resource_leak_detector.clj

@@ -88,7 +88,8 @@
       (.buffer 1)
       (.touch hint)))
 
-(def current-leaks)
+;; NOTE: Not setting to bare `nil` to appease `clj-kondo`.
+(def current-leaks (atom nil))
 
 (defn force-leak-detection! []
   (System/gc)
@@ -131,23 +132,30 @@
       (await-probe! hint)
       (handle-leaks (remove-probes @current-leaks)))))
 
+(defn log-leaks! [leaks]
+  (doseq [{:keys [resource-type records]} leaks]
+    ;; Log message cribbed from io.netty.util.ResourceLeakDetector's (protected) reportTracedLeak method
+    (log/error (str "LEAK: " resource-type ".release() was not called before it's garbage-collected.")
+               (str "See https://netty.io/wiki/reference-counted-objects.html for more information." records))))
+
 (defn -needReport [_this]
   true)
 
+(defn report-leak! [leak]
+  (if @current-leaks
+    (swap! current-leaks conj leak)
+    (do
+      (log/error "NOTE: The following leak occurred outside of a `with-leak-collection` scope.")
+      (log-leaks! [leak]))))
+
 (defn -reportTracedLeak [_this resource-type records]
-  (swap! current-leaks conj {:resource-type resource-type
-                             :records records}))
+  (report-leak! {:resource-type resource-type
+                 :records records}))
 
 ;; NOTE: Since we require level PARANOID, this should never be called in practice.
 (defn -reportUntracedLeak [_this resource-type]
-  (swap! current-leaks conj {:resource-type resource-type
-                             :records "[untraced]"}))
-
-(defn log-leaks! [leaks]
-  (doseq [{:keys [resource-type records]} leaks]
-    ;; Log message cribbed from io.netty.util.ResourceLeakDetector's (protected) reportTracedLeak method
-    (log/error (str "LEAK: " resource-type ".release() was not called before it's garbage-collected.")
-               (str "See https://netty.io/wiki/reference-counted-objects.html for more information." records))))
+  (report-leak! {:resource-type resource-type
+                 :records "[untraced]"}))
 
 (defmacro with-expected-leaks
   "Runs `body` and expects it to produce exactly `expected-leak-count` leaks. Intended for use in tests