Added HTTP module, demonstrating delaying all responses by 1 second

Author: fantix

MANIFEST.in

@@ -4,6 +4,7 @@ include HISTORY.rst
 include LICENSE
 include README.rst
 include nginx/config
+include nginx/ngx_python_module.h
 
 recursive-include nginx *.pyx
 recursive-include nginx *.pxd

nginx/__init__.py

@@ -8,7 +8,8 @@
 
 try:
     from ._nginx import (
-        Cycle, Log, get_current_cycle,
+        Cycle, Log, get_current_cycle, ReturnCode,
+        Request,
         NginxEventLoop, NginxEventLoopPolicy, Event,
     )
 except ImportError:

nginx/hooks.py

@@ -1,6 +1,7 @@
 import asyncio
 import logging
 
+from . import ReturnCode
 from .module import load_modules, _modules
 
 log = logging.Logger(__name__)
@@ -34,5 +35,10 @@ def exit_process():
     _modules.clear()
 
 
-def post_read():
-    log.critical('post read hook!')
+def post_read(request):
+    rv = ReturnCode.declined
+    for mod in _modules:
+        rv = mod.post_read(request)
+        if rv != ReturnCode.declined:
+            return rv
+    return rv

nginx/http/__init__.py

@@ -0,0 +1 @@
+from .module import HTTPModule

nginx/http/http.pyx

@@ -0,0 +1,61 @@
+from cpython cimport Py_INCREF, Py_DECREF
+from .nginx_core cimport ngx_log_error, NGX_LOG_CRIT, NGX_AGAIN
+from .ngx_http cimport ngx_http_request_t, ngx_http_core_run_phases
+from .ngx_http cimport ngx_http_get_module_ctx, ngx_http_set_ctx
+
+import traceback
+
+
+cdef class Request:
+    cdef:
+        ngx_http_request_t *request
+        public Log log
+        object future
+
+    def __init__(self, *args):
+        raise NotImplementedError
+
+    def _started(self):
+        return self.future is not None
+
+    def _start(self, fut):
+        self.future = fut
+        Py_INCREF(self)
+        return NGX_AGAIN
+
+    def _result(self):
+        if self.future.done():
+            Py_DECREF(self)
+            ngx_http_set_ctx(self.request, NULL, ngx_python_module)
+            return self.future.result()
+        return NGX_AGAIN
+
+    @staticmethod
+    cdef Request from_ptr(ngx_http_request_t *request):
+        cdef:
+            void *rv
+            Request new_req
+        rv = ngx_http_get_module_ctx(request, ngx_python_module)
+        if rv == NULL:
+            new_req = Request.__new__(Request)
+            new_req.request = request
+            new_req.log = Log.from_ptr(request.connection.log)
+            ngx_http_set_ctx(request, <void *>new_req, ngx_python_module)
+            return new_req
+        else:
+            return <object>rv
+
+
+cdef public ngx_int_t nginxpy_post_read(ngx_http_request_t *request):
+    try:
+        from . import hooks
+        return hooks.post_read(Request.from_ptr(request))
+    except:
+        ngx_log_error(NGX_LOG_CRIT, request.connection.log, 0,
+                      b'Error occured in post_read:\n' +
+                      traceback.format_exc().encode())
+        return 500
+
+
+def run_phases(Request request):
+    ngx_http_core_run_phases(request.request)

nginx/http/module.py

@@ -0,0 +1,30 @@
+import asyncio
+import logging
+
+from .._nginx import run_phases
+from ..module import BaseModule, ReturnCode
+
+log = logging.getLogger(__name__)
+
+
+class HTTPModule(BaseModule):
+    def __init__(self):
+        self.loop = None
+
+    def init_process(self):
+        self.loop = asyncio.get_event_loop()
+
+    def post_read(self, request):
+        if request._started():
+            return request._result()
+        else:
+            return request._start(self.loop.create_task(self._handle(request)))
+
+    async def _handle(self, request):
+        try:
+            log.info('Handling request...')
+            await asyncio.sleep(1)
+            log.info('Done')
+            return ReturnCode.declined
+        finally:
+            self.loop.call_soon(run_phases, request)

nginx/module.py

@@ -1,6 +1,8 @@
 import logging
 import pkg_resources
 
+from . import ReturnCode
+
 log = logging.Logger(__name__)
 _modules = []
 
@@ -15,11 +17,17 @@ async def after_init_process(self):
     def exit_process(self):
         pass
 
+    def post_read(self, request):
+        return ReturnCode.declined
+
 
 def load_modules():
     log.debug('loading modules')
-    for ep in pkg_resources.iter_entry_points('nginx', 'module'):
-        log.debug('loading %s', ep.module_name)
+    endpoints = [ep for d in pkg_resources.working_set for ep in
+                 d.get_entry_map('nginx.modules').values()]
+    endpoints.sort(key=lambda ep: ep.name)
+    for ep in endpoints:
+        log.info('loading %s', ep.module_name)
         mod = ep.load()
-        log.debug('installing %s', mod)
+        log.info('installing %s', mod)
         _modules.append(mod())

nginx/nginx.pyx

@@ -1,21 +1,32 @@
 # cython: language_level=3
 
 import traceback
+from enum import IntEnum
 
 from .nginx_config cimport ngx_int_t
-from .nginx_core cimport ngx_cycle_t
-from .nginx_core cimport NGX_OK, NGX_ERROR
+from .nginx_core cimport ngx_module_t, ngx_cycle_t
+from .nginx_core cimport NGX_OK, NGX_ERROR, NGX_DECLINED, NGX_AGAIN
 from .nginx_core cimport NGX_LOG_DEBUG, NGX_LOG_CRIT
 from .nginx_core cimport ngx_log_error
 
-from . import hooks
+
+cdef extern from "ngx_python_module.h":
+    ngx_module_t ngx_python_module
+
+
+class ReturnCode(IntEnum):
+    ok = NGX_OK
+    error = NGX_ERROR
+    declined = NGX_DECLINED
+    again = NGX_AGAIN
 
 
 cdef public ngx_int_t nginxpy_init_process(ngx_cycle_t *cycle):
     ngx_log_error(NGX_LOG_DEBUG, cycle.log, 0,
                   b'Starting init_process.')
     # noinspection PyBroadException
     try:
+        from . import hooks
         global current_cycle
         current_cycle = Cycle.from_ptr(cycle)
         set_last_resort(current_cycle.log)
@@ -36,6 +47,7 @@ cdef public void nginxpy_exit_process(ngx_cycle_t *cycle):
                   b'Starting exit_process.')
     # noinspection PyBroadException
     try:
+        from . import hooks
         global current_cycle
         hooks.exit_process()
         unset_last_resort()
@@ -49,10 +61,7 @@ cdef public void nginxpy_exit_process(ngx_cycle_t *cycle):
                       b'Finished exit_process.')
 
 
-cdef public void nginxpy_post_read():
-    hooks.post_read()
-
-
 include "log.pyx"
 include "cycle.pyx"
+include "http/http.pyx"
 include "asyncio/loop.pyx"

nginx/nginx_core.pxd

@@ -3,6 +3,8 @@ from .nginx_config cimport ngx_int_t, ngx_uint_t
 cdef extern from "ngx_core.h":
     const ngx_int_t NGX_OK
     const ngx_int_t NGX_ERROR
+    const ngx_int_t NGX_DECLINED
+    const ngx_int_t NGX_AGAIN
 
     const int NGX_LOG_EMERG
     const int NGX_LOG_ALERT
@@ -16,6 +18,9 @@ cdef extern from "ngx_core.h":
     ctypedef int ngx_err_t
     ctypedef int ngx_msec_t
 
+    ctypedef struct ngx_module_t:
+        pass
+
     ctypedef struct ngx_log_t:
         pass
 

nginx/ngx_http.pxd

@@ -0,0 +1,15 @@
+from .nginx_core cimport ngx_module_t, ngx_log_t
+
+
+cdef extern from "ngx_http.h":
+    ctypedef struct ngx_connection_t:
+        ngx_log_t *log
+
+    ctypedef struct ngx_http_request_t:
+        ngx_connection_t *connection
+
+    void ngx_http_core_run_phases(ngx_http_request_t *request)
+    void *ngx_http_get_module_ctx(ngx_http_request_t *request,
+                                  ngx_module_t module)
+    void ngx_http_set_ctx(ngx_http_request_t *request, void *ctx,
+                          ngx_module_t module)