Simplify examples (#84)

Remove progress-printing from examples in order to simplify them. Also
add tasks to run all examples so that #83 doesn't happen again.

Author: gabrielfeo

examples/build.gradle.kts

@@ -0,0 +1,39 @@
+val exampleTestTasks = ArrayList<TaskProvider<*>>()
+
+exampleTestTasks += tasks.register<Exec>("runExampleScript") {
+    group = "Application"
+    description = "Runs the 'example-script.main.kts' script"
+    commandLine("kotlinc", "-script", file("example-script.main.kts"))
+}
+
+exampleTestTasks += tasks.register<GradleBuild>("runExampleProject") {
+    group = "Verification"
+    description = "Runs examples/example-project as a standalone build"
+    dir = file("example-project")
+    tasks = listOf("run")
+}
+
+val notebooks = fileTree(file("example-notebooks")) {
+    exclude(".ipynb_checkpoints")
+}
+
+exampleTestTasks += notebooks.map { notebook ->
+    val buildDir = project.layout.buildDirectory.asFile.get()
+    tasks.register<Exec>("run${notebook.nameWithoutExtension}Notebook") {
+        group = "Application"
+        description = "Runs the '${notebook.name}' notebook with 'jupyter nbconvert --execute'"
+        commandLine(
+            "jupyter", "nbconvert",
+            "--execute",
+            "--to", "ipynb",
+            "--output-dir=$buildDir",
+            notebook,
+        )
+    }
+}
+
+tasks.register("runExamples") {
+    group = "Application"
+    description = "Runs everything in 'examples' directory"
+    dependsOn(exampleTestTasks)
+}