properly handle $dynamicRef when evaluating a subschema

This occurred in OpenAPI-Modern when trying to do this in t/parameters.t:

    my $result = $openapi->evaluator->evaluate(
      $param_obj,
      OpenAPI::Modern::Utilities::DEFAULT_METASCHEMA->{3.2}.'#/$defs/parameter',
    );
    fail('parameter object is valid'), note($result), next if not $result->valid;

..and we got a 'Reference vivified' error when trying to fetch the resource
corresponding to the dynamic scope uri, which erroneously had a fragment and
therefore was not resolvable.

Author: karenetheridge

Changes

@@ -1,6 +1,8 @@
 Revision history for JSON-Schema-Modern
 
 {{$NEXT}}
+          - fix error when navigating a $dynamicRef after initial evaluation
+            at a subschema
 
 0.622     2025-11-08 22:22:19Z
           - allow export of JSON::Schema::Modern::Utilities::is_bool

lib/JSON/Schema/Modern.pm

@@ -414,7 +414,7 @@ sub evaluate ($self, $data, $schema_reference, $config_override = {}) {
       %$state,
       initial_schema_uri => $schema_info->{canonical_uri}, # the canonical URI as of the start of evaluation, or last $id or $ref
       $schema_info->%{qw(document specification_version vocabularies)},
-      dynamic_scope => [ $schema_info->{canonical_uri} ],
+      dynamic_scope => [ $schema_info->{canonical_uri}->clone->fragment(undef) ],
       annotations => [],
       seen => {},
       callbacks => $config_override->{callbacks} // {},
@@ -843,7 +843,10 @@ has _resource_index => (
     ]],
 );
 
-sub _get_resource { ($_[0]->{_resource_index}//{})->{$_[1]} }
+sub _get_resource {
+  die 'bad resource: ', $_[1] if $_[1] =~ /#/;
+  ($_[0]->{_resource_index}//{})->{$_[1]}
+}
 
 # does not check for duplicate entries, or for malformed uris
 sub _add_resources_unsafe {

lib/JSON/Schema/Modern/Vocabulary/Core.pm

@@ -336,6 +336,7 @@ sub _eval_keyword_dynamicRef ($class, $data, $schema, $state) {
     # "$dynamicAnchor".
     foreach my $scope_uri ($state->{dynamic_scope}->@*) {
       my $resource = $state->{evaluator}->_get_or_load_resource($scope_uri);
+      die 'bad dynamic scope uri: ', $scope_uri if not $resource;
       if (exists(($resource->{anchors}//{})->{$anchor}) and $resource->{anchors}{$anchor}{dynamic}) {
         $uri = Mojo::URL->new($scope_uri)->fragment($anchor);
         last;

t/ref.t

@@ -1293,4 +1293,65 @@ subtest 'evaluate at a non-schema location' => sub {
   );
 };
 
+subtest 'evaluate at a subschema, with $dynamicRef' => sub {
+  # from a real bug I encountered while writing a t/parameters.t test in OpenAPI-Modern!
+  # if we evaluate in the middle of a document, and a $dynamicRef is involved, mayhem ensues.
+  $js->{_resource_index} = {};
+  $js->add_schema({
+    '$id' => 'http://strict_metaschema',
+    '$defs' => {
+      schema => {
+        '$dynamicAnchor' => 'meta',
+        type => 'object', # disallows boolean
+      },
+      parameter => {
+        '$ref' => 'http://loose_metaschema#/$defs/parameter',
+      },
+    },
+    '$ref' => 'http://loose_metaschema#/intentionally/bad/reference',
+  });
+
+  $js->add_schema({
+    '$id' => 'http://loose_metaschema',
+    '$defs' => {
+      schema => {
+        '$dynamicAnchor' => 'meta',
+        type => [ 'object', 'boolean' ],
+      },
+      parameter => {
+        type => 'object',
+        properties => {
+          name => { type => 'string' },
+          schema => { '$dynamicRef' => '#meta' },
+        },
+      },
+    },
+  });
+
+  cmp_result(
+    $js->evaluate(
+      { name => 'hi', schema => false },
+      'http://strict_metaschema#/$defs/parameter',
+    )->TO_JSON,
+    {
+      valid => false,
+      errors => [
+        {
+          instanceLocation => '/schema',
+          keywordLocation => '/$ref/properties/schema/$dynamicRef/type',
+          absoluteKeywordLocation => 'http://strict_metaschema#/$defs/schema/type',
+          error => 'got boolean, not object',
+        },
+        {
+          instanceLocation => '',
+          keywordLocation => '/$ref/properties',
+          absoluteKeywordLocation => 'http://loose_metaschema#/$defs/parameter/properties',
+          error => 'not all properties are valid',
+        },
+      ],
+    },
+    'correctly navigated a $dynamicRef while evaluating in the middle of a document',
+  );
+};
+
 done_testing;