lib/vim-plugin: Add a luaConfig option similar to mkNeovimPlugin

Author: traxys

lib/neovim-plugin.nix

@@ -123,7 +123,7 @@
             }
             // lib.optionalAttrs hasConfigAttrs {
               luaConfig = lib.mkOption {
-                type = lib.types.pluginLuaConfig;
+                type = lib.types.pluginLuaConfig { hasContent = true; };
                 default = { };
                 description = "The plugin's lua configuration";
               };

lib/types.nix

@@ -137,47 +137,60 @@ rec {
       }";
     };
 
-  pluginLuaConfig = types.submodule (
-    { config, ... }:
-    let
-      inherit (builtins) toString;
-      inherit (lib.nixvim.utils) mkBeforeSection mkAfterSection;
-    in
-    {
-      options = {
-        pre = lib.mkOption {
-          type = with types; nullOr lines;
-          default = null;
-          description = ''
-            Lua code inserted at the start of the plugin's configuration.
-            This is the same as using `lib.nixvim.utils.mkBeforeSection` when defining `content`.
-          '';
-        };
-        post = lib.mkOption {
-          type = with types; nullOr lines;
-          default = null;
-          description = ''
-            Lua code inserted at the end of the plugin's configuration.
-            This is the same as using `lib.nixvim.utils.mkAfterSection` when defining `content`.
-          '';
-        };
-        content = lib.mkOption {
-          type = types.lines;
-          default = "";
-          description = ''
-            Configuration of the plugin.
+  pluginLuaConfig =
+    { hasContent }:
+    types.submodule (
+      { config, ... }:
+      let
+        inherit (builtins) toString;
+        inherit (lib.nixvim.utils) mkBeforeSection mkAfterSection;
+      in
+      {
+        options =
+          {
+            pre = lib.mkOption {
+              type = with types; nullOr lines;
+              default = null;
+              description =
+                ''
+                  Lua code inserted at the start of the plugin's configuration.
+                ''
+                + lib.optionalString hasContent ''
+                  This is the same as using `lib.nixvim.utils.mkBeforeSection` when defining `content`.
+                '';
+            };
+            post = lib.mkOption {
+              type = with types; nullOr lines;
+              default = null;
+              description =
+                ''
+                  Lua code inserted at the end of the plugin's configuration.
+                ''
+                + lib.optionalString hasContent ''
+                  This is the same as using `lib.nixvim.utils.mkAfterSection` when defining `content`.
+                '';
+            };
+          }
+          // (lib.optionalAttrs hasContent) {
+            content = lib.mkOption {
+              type = types.lines;
+              default = "";
+              description = ''
+                Configuration of the plugin.
 
-            If `pre` and/or `post` are non-null, they will be merged using the order priorities
-            ${toString (mkBeforeSection null).priority} and ${toString (mkBeforeSection null).priority}
-            respectively.
-          '';
-        };
-      };
+                If `pre` and/or `post` are non-null, they will be merged using the order priorities
+                ${toString (mkBeforeSection null).priority} and ${toString (mkBeforeSection null).priority}
+                respectively.
+              '';
+            };
+          };
 
-      config.content = lib.mkMerge (
-        lib.optional (config.pre != null) (mkBeforeSection config.pre)
-        ++ lib.optional (config.post != null) (mkAfterSection config.post)
-      );
-    }
-  );
+        config = lib.optionalAttrs hasContent {
+          content = lib.mkMerge (
+            lib.optional (config.pre != null) (mkBeforeSection config.pre)
+            ++ lib.optional (config.post != null) (mkAfterSection config.post)
+          );
+        };
+      }
+    );
 }

lib/vim-plugin.nix

@@ -49,6 +49,12 @@
             - `other_toggle = false` -> `:setglobal no${globalPrefix}other_toggle`
           '';
         };
+
+        luaConfig = lib.mkOption {
+          type = lib.types.pluginLuaConfig { hasContent = false; };
+          default = { };
+          description = "The plugin's lua configuration";
+        };
       };
 
       module =
@@ -113,7 +119,9 @@
                 extraPlugins = extraPlugins ++ [
                   (cfg.packageDecorator cfg.package)
                 ];
+                globalsPre = cfg.luaConfig.pre;
                 globals = lib.mapAttrs' (n: lib.nameValuePair (globalPrefix + n)) (cfg.settings or { });
+                globalsPost = cfg.luaConfig.post;
               }
               (lib.optionalAttrs (isColorscheme && (colorscheme != null)) {
                 colorscheme = lib.mkDefault colorscheme;

modules/opts.nix

@@ -84,23 +84,25 @@ in
               optionDefinitions = helpers.toLuaObject config.${optionName};
               ifGlobals = lib.optionalString (optionName == "globals");
             in
-            lib.optionalString (optionDefinitions != "{ }") ''
-              -- Set up ${prettyName} {{{
-            ''
-            + (ifGlobals config.globalsPre)
-            + ''
-              do
-                local ${varName} = ${optionDefinitions}
+            lib.optionalString (optionDefinitions != "{ }") (
+              ''
+                -- Set up ${prettyName} {{{
+              ''
+              + (ifGlobals config.globalsPre)
+              + ''
+                do
+                  local ${varName} = ${optionDefinitions}
 
-                for k,v in pairs(${varName}) do
-                  vim.${luaApi}[k] = v
+                  for k,v in pairs(${varName}) do
+                    vim.${luaApi}[k] = v
+                  end
                 end
-              end
-            ''
-            + (ifGlobals config.globalsPost)
-            + ''
-              -- }}}
-            ''
+              ''
+              + (ifGlobals config.globalsPost)
+              + ''
+                -- }}}
+              ''
+            )
           ) optionsAttrs
         );
       in

tests/test-sources/plugins/lua-config.nix

@@ -23,4 +23,24 @@
       end
     '';
   };
+  lua-config-vim-plugin = {
+    plugins.typst-vim = {
+      enable = true;
+      luaConfig.pre = # lua
+        ''
+          local command = "typst-wrapped" -- Let's say we got it through env vars 
+        '';
+      settings.cmd.__raw = "command";
+      luaConfig.post = # lua
+        ''
+          local globals_cmd = vim.g.typst_cmd
+        '';
+    };
+
+    extraConfigLuaPost = ''
+      if globals_cmd ~= command then
+        print("globals_cmd different than command: " .. globals_cmd .. ", " .. command)
+      end
+    '';
+  };
 }