Lesson 7 - Lottery Constructor error on compile

[Dave777]

Hi,
When trying to "brownie compile" the lottery stack I get this error which I can
not understand !!! (see below)

Here is my code

Lottery.sol

// SPDX-License-Identifier: GPL-3.0

pragma solidity >=0.6.0 <0.9.0;

import "@chainlink/contracts/src/v0.6/interfaces/AggregatorV3Interface.sol";

contract Lottery {
    address payable[] public players;
    uint256 public usdEntryFee;
    AggregatorV3Interface internal ethUsdPriceFeed;
    enum LOTTERY_STATE {
        OPEN,
        CLOSED,
        SELECTING_WINNER
    }
    LOTTERY_STATE public lottery_state;

    constructor(address _priceFeedAddress) public {
        usdEntryFee = 50 * (10**18);
        ethUsdPriceFeed = AggregatorV3Interface(_priceFeedAddress);
        lottery_state = LOTTERY_STATE.CLOSED;
    }

    function enter() public payable {
        // $50 entrance
        require(
            msg.value >= getEntranceFee(),
            "Not enough Eth to meet min Entry 50 usd"
        );
        players.push(msg.sender);
    }

    function getEntranceFee() public view returns (uint256) {
        (, int256 price, , , ) = ethUsdPriceFeed.latestRoundData();
        uint256 adjustedPrice = uint256(price) * 10**10; // 18 decimals
        uint256 costToEnter = (usdEntryFee * 10**18) / adjustedPrice;
        return costToEnter;
    }

    function startLot() public {}

    function endLot() public {}
}

and the brownie-config.yaml

dependencies:
  - smartcontractkit/chainlink-brownie-contracts@1.1.1
compiler:
  solc:
    remappings: "@chainlink=smartcontractkit/chainlink-brownie-contracts@1.1.1"

networks:
  mainnet-fork:
    eth_usd_price_feed: "0x5f4eC3Df9cbd43714FE2740f5E3616155c5b8419"

This is the full error message:

PS D:\aa_python3\BLOCK\lottery> brownie compile
INFO: Could not find files for the given pattern(s).
Brownie v1.16.4 - Python development framework for Ethereum

Compiling contracts...
  Solc version: 0.8.11
  Optimizer: Enabled  Runs: 200
  EVM Version: Istanbul
CompilerError: solc returned the following errors:

Warning: Visibility for constructor is ignored. If you want the contract to be non-deployable, making it "abstract" is sufficient.
  --> contracts/Lottery.sol:18:5:
   |
18 |     constructor(address _priceFeedAddress) public {
   |     ^ (Relevant source part starts here and spans across multiple lines).


TypeError: Member "push" not found or not visible after argument-dependent lookup in address payable[] storage ref.
  --> contracts/Lottery.sol:30:9:
   |
30 |         players.push(msg.sender);
   |         ^^^^^^^^^^^^

PS D:\aa_python3\BLOCK\lottery> 

Hope you can spot my error,
many thanks

[freddie71010]

You need to convert msg.sender to a payable address since you cannot add a non-payable address to an array.

Update your enter() function to include players.push(payable(msg.sender));

    function enter() public payable {
        require(lottery_state == LOTTERY_STATE.OPEN);
        require(msg.value >= getEntranceFee(), "Not enough ETH!");
        players.push(payable(msg.sender));
    }

[JohnEMagee]

This should be marked as the answer as I'm in an even earlier state and this solved my problem

[cromewar]

Hello @Dave777. first of all you can remove the public identifier from here:

  constructor(address _priceFeedAddress) public {
        usdEntryFee = 50 * (10**18);
        ethUsdPriceFeed = AggregatorV3Interface(_priceFeedAddress);
        lottery_state = LOTTERY_STATE.CLOSED;
    }

And @freddie71010 is right, in solidity v 0.8.0 the directions are not automatically payable, so you can use his solution, also you can refer here for more information.