Implement binary formatter for Logger

Author: ream88

.formatter.exs

@@ -0,0 +1,4 @@
+# Used by "mix format"
+[
+  inputs: ["{mix,.formatter}.exs", "{config,lib,test}/**/*.{ex,exs}"]
+]

.gitignore

@@ -0,0 +1,26 @@
+# The directory Mix will write compiled artifacts to.
+/_build/
+
+# If you run "mix test --cover", coverage assets end up here.
+/cover/
+
+# The directory Mix downloads your dependencies sources to.
+/deps/
+
+# Where third-party dependencies like ExDoc output generated docs.
+/doc/
+
+# Ignore .fetch files in case you like to edit your project deps locally.
+/.fetch
+
+# If the VM crashes, it generates a dump, let's ignore it too.
+erl_crash.dump
+
+# Also ignore archive artifacts (built via "mix archive.build").
+*.ez
+
+# Ignore package tarball (built via "mix hex.build").
+logger_binary-*.tar
+
+# Temporary files, for example, from tests.
+/tmp/

README.md

@@ -0,0 +1,53 @@
+# LoggerBinary
+
+A custom `Logger` formatter for handling binary data.
+
+  This formatter is designed to correctly format binary messages. It converts
+  non-printable binary data into a hexadecimal string representation and can
+  optionally add a directional indicator (`"< "` or `"> "`) when needed.
+
+  ## Usage
+
+      config :logger, :console,
+        format: {LoggerBinary.Formatter, :format},
+        metadata: [:direction]
+
+  ## Features
+
+    * Formats binary messages as uppercase hexadecimal strings.
+    * Prepends formatted binary messages with a directional indicator if the `:direction`
+      metadata is present. Supported values for the `:direction` metadata are `:in` and `:out`.
+    * Uses the default Logger format for all other types of messages (e.g., printable strings and charlists).
+
+  ## Direction Indicator
+
+  You can add the `:direction` metadata to your log messages to indicate if the
+  binary data is an incoming or outgoing message:
+
+      Logger.debug(<<0x01, 0x02, 0x03>>, direction: :in)
+      # Logs: "[debug] < 01 02 03"
+
+      Logger.debug(<<0x01, 0x02, 0x03>>, direction: :out)
+      # Logs: "[debug] > 01 02 03"
+
+  Without directional metadata, it simply logs the formatted binary:
+
+      Logger.debug(<<0x01, 0x02, 0x03>>)
+      # Logs: "[debug] 01 02 03"
+
+## Installation
+
+If [available in Hex](https://hex.pm/docs/publish), the package can be installed
+by adding `logger_binary` to your list of dependencies in `mix.exs`:
+
+```elixir
+def deps do
+  [
+    {:logger_binary, "~> 0.1.0"}
+  ]
+end
+```
+
+Documentation can be generated with [ExDoc](https://github.com/elixir-lang/ex_doc)
+and published on [HexDocs](https://hexdocs.pm). Once published, the docs can
+be found at <https://hexdocs.pm/logger_binary>.

config/config.exs

@@ -0,0 +1,5 @@
+import Config
+
+config :logger, :console,
+  format: {LoggerBinary.Formatter, :format},
+  metadata: [:direction]

lib/logger_binary.ex

@@ -0,0 +1,38 @@
+defmodule LoggerBinary do
+  @moduledoc """
+  A custom `Logger` formatter for handling binary data.
+
+  This formatter is designed to correctly format binary messages. It converts
+  non-printable binary data into a hexadecimal string representation and can
+  optionally add a directional indicator (`"< "` or `"> "`) when needed.
+
+  ## Usage
+
+      config :logger, :console,
+        format: {LoggerBinary.Formatter, :format},
+        metadata: [:direction]
+
+  ## Features
+
+    * Formats binary messages as uppercase hexadecimal strings.
+    * Prepends formatted binary messages with a directional indicator if the `:direction`
+      metadata is present. Supported values for the `:direction` metadata are `:in` and `:out`.
+    * Uses the default Logger format for all other types of messages (e.g., printable strings and charlists).
+
+  ## Direction Indicator
+
+  You can add the `:direction` metadata to your log messages to indicate if the
+  binary data is an incoming or outgoing message:
+
+      Logger.debug(<<0x01, 0x02, 0x03>>, direction: :in)
+      # Logs: "[debug] < 01 02 03"
+
+      Logger.debug(<<0x01, 0x02, 0x03>>, direction: :out)
+      # Logs: "[debug] > 01 02 03"
+
+  Without directional metadata, it simply logs the formatted binary:
+
+      Logger.debug(<<0x01, 0x02, 0x03>>)
+      # Logs: "[debug] 01 02 03"
+  """
+end

lib/logger_binary/formatter.ex

@@ -0,0 +1,33 @@
+defmodule LoggerBinary.Formatter do
+  @moduledoc false
+
+  @default_format Logger.Formatter.compile(
+                    Application.compile_env(:config, [:console, :format], "[$level] $message\n")
+                  )
+
+  def format(level, message, timestamp, metadata) when is_binary(message) do
+    message =
+      if String.printable?(message) do
+        message
+      else
+        formatted_message =
+          message
+          |> Base.encode16(case: :upper)
+          |> String.graphemes()
+          |> Enum.chunk_every(2)
+          |> Enum.map_join(" ", &Enum.join(&1))
+
+        case Keyword.get(metadata, :direction) do
+          :in -> "< " <> formatted_message
+          :out -> "> " <> formatted_message
+          _ -> formatted_message
+        end
+      end
+
+    Logger.Formatter.format(@default_format, level, message, timestamp, metadata)
+  end
+
+  def format(level, message, timestamp, metadata) do
+    Logger.Formatter.format(@default_format, level, message, timestamp, metadata)
+  end
+end

mix.exs

@@ -0,0 +1,27 @@
+defmodule LoggerBinary.MixProject do
+  use Mix.Project
+
+  def project do
+    [
+      app: :logger_binary,
+      version: "0.1.0",
+      elixir: "~> 1.16",
+      start_permanent: Mix.env() == :prod,
+      deps: deps()
+    ]
+  end
+
+  # Run "mix help compile.app" to learn about applications.
+  def application do
+    [
+      extra_applications: [:logger]
+    ]
+  end
+
+  # Run "mix help deps" to learn about dependencies.
+  defp deps do
+    [
+      {:ex_doc, "~> 0.36.1", only: :dev, runtime: false}
+    ]
+  end
+end

mix.lock

@@ -0,0 +1,8 @@
+%{
+  "earmark_parser": {:hex, :earmark_parser, "1.4.43", "34b2f401fe473080e39ff2b90feb8ddfeef7639f8ee0bbf71bb41911831d77c5", [:mix], [], "hexpm", "970a3cd19503f5e8e527a190662be2cee5d98eed1ff72ed9b3d1a3d466692de8"},
+  "ex_doc": {:hex, :ex_doc, "0.36.1", "4197d034f93e0b89ec79fac56e226107824adcce8d2dd0a26f5ed3a95efc36b1", [:mix], [{:earmark_parser, "~> 1.4.42", [hex: :earmark_parser, repo: "hexpm", optional: false]}, {:makeup_c, ">= 0.1.0", [hex: :makeup_c, repo: "hexpm", optional: true]}, {:makeup_elixir, "~> 0.14 or ~> 1.0", [hex: :makeup_elixir, repo: "hexpm", optional: false]}, {:makeup_erlang, "~> 0.1 or ~> 1.0", [hex: :makeup_erlang, repo: "hexpm", optional: false]}, {:makeup_html, ">= 0.1.0", [hex: :makeup_html, repo: "hexpm", optional: true]}], "hexpm", "d7d26a7cf965dacadcd48f9fa7b5953d7d0cfa3b44fa7a65514427da44eafd89"},
+  "makeup": {:hex, :makeup, "1.2.1", "e90ac1c65589ef354378def3ba19d401e739ee7ee06fb47f94c687016e3713d1", [:mix], [{:nimble_parsec, "~> 1.4", [hex: :nimble_parsec, repo: "hexpm", optional: false]}], "hexpm", "d36484867b0bae0fea568d10131197a4c2e47056a6fbe84922bf6ba71c8d17ce"},
+  "makeup_elixir": {:hex, :makeup_elixir, "1.0.1", "e928a4f984e795e41e3abd27bfc09f51db16ab8ba1aebdba2b3a575437efafc2", [:mix], [{:makeup, "~> 1.0", [hex: :makeup, repo: "hexpm", optional: false]}, {:nimble_parsec, "~> 1.2.3 or ~> 1.3", [hex: :nimble_parsec, repo: "hexpm", optional: false]}], "hexpm", "7284900d412a3e5cfd97fdaed4f5ed389b8f2b4cb49efc0eb3bd10e2febf9507"},
+  "makeup_erlang": {:hex, :makeup_erlang, "1.0.1", "c7f58c120b2b5aa5fd80d540a89fdf866ed42f1f3994e4fe189abebeab610839", [:mix], [{:makeup, "~> 1.0", [hex: :makeup, repo: "hexpm", optional: false]}], "hexpm", "8a89a1eeccc2d798d6ea15496a6e4870b75e014d1af514b1b71fa33134f57814"},
+  "nimble_parsec": {:hex, :nimble_parsec, "1.4.2", "8efba0122db06df95bfaa78f791344a89352ba04baedd3849593bfce4d0dc1c6", [:mix], [], "hexpm", "4b21398942dda052b403bbe1da991ccd03a053668d147d53fb8c4e0efe09c973"},
+}

test/logger_binary/formatter_test.exs

@@ -0,0 +1,36 @@
+defmodule LoggerBinary.FormatterTest do
+  use ExUnit.Case, async: true
+
+  require Logger
+  import ExUnit.CaptureLog
+
+  test "formats binary data" do
+    assert capture_log(fn ->
+             Logger.debug(<<0x01, 0x02, 0x03>>)
+           end) =~ "[debug] 01 02 03"
+  end
+
+  test "formats binary input" do
+    assert capture_log(fn ->
+             Logger.debug(<<0x01, 0x02, 0x03>>, direction: :in)
+           end) =~ "[debug] < 01 02 03"
+  end
+
+  test "formats binary output" do
+    assert capture_log(fn ->
+             Logger.debug(<<0x01, 0x02, 0x03>>, direction: :out)
+           end) =~ "[debug] > 01 02 03"
+  end
+
+  test "ignores any other binary message" do
+    assert capture_log(fn ->
+             Logger.debug("message")
+           end) =~ "[debug] message"
+  end
+
+  test "ignores charlist messages" do
+    assert capture_log(fn ->
+             Logger.debug(~c"message")
+           end) =~ "[debug] message"
+  end
+end

test/test_helper.exs

@@ -0,0 +1 @@
+ExUnit.start()