Finish making ParseXS build an AST and fix some bugs

dist/ExtUtils-ParseXS/lib/ExtUtils/ParseXS.pm

@@ -883,67 +883,6 @@ sub push_parse_stack {
 }
 
 
-sub INCLUDE_handler {
-  my ExtUtils::ParseXS $self = shift;
-  $_ = shift;
-  # the rest of the current line should contain a valid filename
-
-  trim_whitespace($_);
-
-  $self->death("INCLUDE: filename missing")
-    unless $_;
-
-  $self->death("INCLUDE: output pipe is illegal")
-    if /^\s*\|/;
-
-  # simple minded recursion detector
-  $self->death("INCLUDE loop detected")
-    if $self->{IncludedFiles}->{$_};
-
-  ++$self->{IncludedFiles}->{$_} unless /\|\s*$/;
-
-  if (/\|\s*$/ && /^\s*perl\s/) {
-    Warn( $self, "The INCLUDE directive with a command is discouraged." .
-          " Use INCLUDE_COMMAND instead! In particular using 'perl'" .
-          " in an 'INCLUDE: ... |' directive is not guaranteed to pick" .
-          " up the correct perl. The INCLUDE_COMMAND directive allows" .
-          " the use of \$^X as the currently running perl, see" .
-          " 'perldoc perlxs' for details.");
-  }
-
-  $self->push_parse_stack();
-
-  $self->{in_fh} = Symbol::gensym();
-
-  # open the new file
-  open($self->{in_fh}, $_) or $self->death("Cannot open '$_': $!");
-
-  print Q(<<"EOF");
-    |
-    |/* INCLUDE:  Including '$_' from '$self->{in_filename}' */
-    |
-EOF
-
-  $self->{in_filename} = $_;
-  $self->{in_pathname} = ( $^O =~ /^mswin/i )
-                            # See CPAN RT #61908: gcc doesn't like
-                            # backslashes on win32?
-                          ? qq($self->{dir}/$self->{in_filename})
-                          : File::Spec->catfile($self->{dir}, $self->{in_filename});
-
-  # Prime the pump by reading the first
-  # non-blank line
-
-  # skip leading blank lines
-  while (readline($self->{in_fh})) {
-    last unless /^\s*$/;
-  }
-
-  $self->{lastline} = $_;
-  $self->{lastline_no} = $.;
-}
-
-
 # Quote a command-line to be suitable for VMS
 
 sub QuoteArgs {
@@ -980,58 +919,6 @@ sub QuoteArgs {
 }
 
 
-sub INCLUDE_COMMAND_handler {
-  my ExtUtils::ParseXS $self = shift;
-  $_ = shift;
-  # the rest of the current line should contain a valid command
-
-  trim_whitespace($_);
-
-  $_ = QuoteArgs($_) if $^O eq 'VMS';
-
-  $self->death("INCLUDE_COMMAND: command missing")
-    unless $_;
-
-  $self->death("INCLUDE_COMMAND: pipes are illegal")
-    if /^\s*\|/ or /\|\s*$/;
-
-  $self->push_parse_stack( IsPipe => 1 );
-
-  $self->{in_fh} = Symbol::gensym();
-
-  # If $^X is used in INCLUDE_COMMAND, we know it's supposed to be
-  # the same perl interpreter as we're currently running
-  my $X = $self->_safe_quote($^X); # quotes if has spaces
-  s/^\s*\$\^X/$X/;
-
-  # open the new file
-  open ($self->{in_fh}, "-|", $_)
-    or $self->death( $self, "Cannot run command '$_' to include its output: $!");
-
-  print Q(<<"EOF");
-    |
-    |/* INCLUDE_COMMAND:  Including output of '$_' from '$self->{in_filename}' */
-    |
-EOF
-
-  $self->{in_filename} = $_;
-  $self->{in_pathname} = $self->{in_filename};
-  #$self->{in_pathname} =~ s/\"/\\"/g; # Fails? See CPAN RT #53938: MinGW Broken after 2.21
-  $self->{in_pathname} =~ s/\\/\\\\/g; # Works according to reporter of #53938
-
-  # Prime the pump by reading the first
-  # non-blank line
-
-  # skip leading blank lines
-  while (readline($self->{in_fh})) {
-    last unless /^\s*$/;
-  }
-
-  $self->{lastline} = $_;
-  $self->{lastline_no} = $.;
-}
-
-
 # Pop the type => 'file' entry off the top of the @{ $self->{XS_parse_stack} }
 # array following the end of processing an INCLUDEd file, and restore the
 # former state.

dist/ExtUtils-ParseXS/lib/ExtUtils/ParseXS/Node.pm

@@ -1,6 +1,7 @@
 package ExtUtils::ParseXS::Node;
 use strict;
 use warnings;
+use Symbol;
 
 our $VERSION = '3.61';
 
@@ -3973,6 +3974,175 @@ sub parse {
 }
 
 
+# ======================================================================
+
+package ExtUtils::ParseXS::Node::include;
+
+# Common base class for the 'INCLUDE' and 'INCLUDE_COMMAND' keywords
+
+BEGIN { $build_subclass->(-parent => 'oneline',
+    'is_cmd',       # Bool: is INCLUDE_COMMAND
+    'inc_filename', # Str:  the file/command to be included
+    'old_filename', # Str:  the previous file
+)};
+
+
+sub parse {
+    my __PACKAGE__       $self = shift;
+    my ExtUtils::ParseXS $pxs  = shift;
+
+    $self->SUPER::parse($pxs); # set file/line_no/text
+
+    my $f      = $self->{text};
+    my $is_cmd = $self->{is_cmd};
+
+    if ($is_cmd) {
+        $f = ExtUtils::ParseXS::QuoteArgs($f) if $^O eq 'VMS';
+
+        $pxs->death("INCLUDE_COMMAND: command missing")
+            unless length $f;
+
+        $pxs->death("INCLUDE_COMMAND: pipes are illegal")
+            if $f =~ /^\s*\|/ or $f =~ /\|\s*$/;
+    }
+    else {
+        $pxs->death("INCLUDE: filename missing")
+            unless length $f;
+
+        $pxs->death("INCLUDE: output pipe is illegal")
+            if $f =~ /^\s*\|/;
+
+        # simple minded recursion detector
+        $pxs->death("INCLUDE loop detected")
+            if $pxs->{IncludedFiles}{$f};
+
+        ++$pxs->{IncludedFiles}->{$f} unless $f =~ /\|\s*$/;
+
+        if ($f =~ /\|\s*$/ && $f =~ /^\s*perl\s/) {
+            $pxs->Warn(
+                  "The INCLUDE directive with a command is discouraged."
+                . " Use INCLUDE_COMMAND instead! In particular using 'perl'"
+                . " in an 'INCLUDE: ... |' directive is not guaranteed to pick"
+                . " up the correct perl. The INCLUDE_COMMAND directive allows"
+                . " the use of \$^X as the currently running perl, see"
+                . " 'perldoc perlxs' for details."
+            );
+        }
+    }
+
+    $pxs->push_parse_stack($is_cmd ? (IsPipe => 1) : ());
+
+    $pxs->{in_fh} = Symbol::gensym();
+
+    # Open the new file / pipe
+
+    if ($is_cmd) {
+        # Expand the special token '$^X' into the full path of the
+        # currently running perl interpreter
+        my $X = $pxs->_safe_quote($^X); # quotes if has spaces
+        $f =~ s/^\s*\$\^X/$X/;
+
+        open ($pxs->{in_fh}, "-|", $f)
+            or $pxs->death(
+                "Cannot run command '$f' to include its output: $!");
+    }
+    else {
+        open($pxs->{in_fh}, $f)
+            or $pxs->death("Cannot open '$f': $!");
+    }
+
+    $self->{old_filename} = $pxs->{in_filename};
+    $self->{inc_filename} = $f;
+    $pxs->{in_filename} = $f;
+
+    my $path = $f;
+    if ($is_cmd) {
+        #$path =~ s/\"/\\"/g; # Fails? See CPAN RT #53938: MinGW Broken after 2.21
+        $path =~ s/\\/\\\\/g; # Works according to reporter of #53938
+    }
+    else {
+        $path = ($^O =~ /^mswin/i)
+                      # See CPAN RT #61908: gcc doesn't like
+                      # backslashes on win32?
+                    ? "$pxs->{dir}/$path"
+                    : File::Spec->catfile($pxs->{dir}, $path);
+    }
+    $pxs->{in_pathname} = $path;
+
+    # Prime the pump by reading the first non-blank line
+
+    # skip leading blank lines
+    while (readline($pxs->{in_fh})) {
+        last unless /^\s*$/;
+    }
+
+    $pxs->{lastline} = $_;
+    $pxs->{lastline_no} = $.;
+
+    1;
+}
+
+
+sub as_code {
+    my __PACKAGE__                    $self  = shift;
+    my ExtUtils::ParseXS              $pxs   = shift;
+
+    my $comment = $self->{is_cmd}
+        ?   "INCLUDE_COMMAND:  Including output of"
+        :   "INCLUDE:  Including";
+
+    $comment .= " '$self->{inc_filename}' from '$self->{old_filename}'";
+
+    print ExtUtils::ParseXS::Q(<<"EOF");
+        |
+        |/* $comment */
+        |
+EOF
+}
+
+
+# ======================================================================
+
+package ExtUtils::ParseXS::Node::INCLUDE;
+
+# Process the 'INCLUDE' keyword. Most processing is actually done by the
+# parent 'include' class which handles INCLUDE_COMMAND too.
+
+BEGIN { $build_subclass->(-parent => 'include',
+)};
+
+
+sub parse {
+    my __PACKAGE__       $self = shift;
+    my ExtUtils::ParseXS $pxs  = shift;
+
+    $self->{is_cmd} = 0;
+    $self->SUPER::parse($pxs); # main parsing done by Node::include
+    1;
+}
+
+
+# ======================================================================
+
+package ExtUtils::ParseXS::Node::INCLUDE_COMMAND;
+
+# Process the 'INCLUDE_COMMAND' keyword. Most processing is actually done
+# by the parent 'include' class which handles INCLUDE too.
+
+BEGIN { $build_subclass->(-parent => 'include',
+)};
+
+
+sub parse {
+    my __PACKAGE__       $self = shift;
+    my ExtUtils::ParseXS $pxs  = shift;
+
+    $self->{is_cmd} = 1;
+    $self->SUPER::parse($pxs); # main parsing done by Node::include
+    1;
+}
+
+
 # ======================================================================
 
 package ExtUtils::ParseXS::Node::enable;